Recuperar arquivos ocultos no Pendrive

As vezes nos deparamos com essa situação...

De colocar nosso pendrive em um computador de terceiros, principalmente onde tem um grande fluxo de pessoas utilizando-o, e acontecer de nosso pendrive ser infectado por um pequeno vírus criado em VBS, e esse vírus torna nossos arquivos e pastas ocultas e cria atalhos no pendrive para ser executado outro comando mais nocivo.

Porém se você se deparar com este tipo de situação, basta você utilizar este "pequeno" código em Batch para você fazer todo o processo automático, tornando assim sua vida mais fácil.

O Processo é bem simples.
Primeiro você coloca seu pendrive.
Depois abre o programa e executa-o.
Em seguida digite a letra do Pendrive no Programa e resto é com ele.

Apenas confirme se você realmente deseja continuar, para não ter perigo de você não desejar continuar.

O processo não permite ser usado nos drivers Fixos, só é aplicável em discos removíveis.

Futuramente coloco para ser feita essa verificação nos drivers.

Segue abaixo o código para ser usado livremente por você:

Não altere caso não saiba, problemas provenientes do seu uso e que sejam nocivos, são de inteira responsabilidade sua.

Se sabes utilizar os comandos, então altere ao seu gosto...

Código-Fonte: HiddenPendrive.BAT

:: ÚÄ¿ ³  ÀÄÙ 
@echo off
set ano=2016
set versao=3.0.1.6
set autor=GoScripts
:: variáveis do sistema
set jpl=echo.&echo.&echo.
set dne=Drive nÆo encontrado
set dnp=Drive nÆo permitido
set ldd=Letra do Drive
set fl1=Letra do drive
set tmptxt=string.txt
set string=remov¡vel
set err=ERRO
set put=echo.  Pressione uma Tecla.
set ls=echo. ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
set li=echo. ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
set f1=*.vbs
set f2=*.lnk
set f3=*.pif
set f4=*.com
set f5=*.cmd

:: ====================================================
:: Esta é uma versão manual para verificar o Pendrive
:: você tem que digitar a letra do pendrive no programa
:: em Lotes (batch). 
:: ====================================================

:: ====================================================
:: FAZER A LEITURA DO PENDRIVE
:: ====================================================
:inicio
color F0
MODE 30,6
title HiddenFiles[GoScripts]
cls
echo.
%ls%
echo. ³ %ldd%(Ex: F)³
%li%
set /p "drive=_² Drive: ")
if exist "%drive:~0,1%:" (
 goto :iniprocesso
 ) else (
  cls
  title %err%
  color C0
  %ls%
  %jpl% ³ %dne% ³
  %li%
  %put%
  pause>nul&goto :inicio
   )
:: ====================================================
:: Verifica se é removível ou se é Disco Fixo.
:: Para não ter perigo de usar o disco do sistema.
:: ====================================================
:iniprocesso
color 0A
pushd "%tmp%"
cls
fsutil fsinfo drivetype %drive:~0,1%: >%tmptxt%
find /I %tmptxt% "%string%"
if %errorlevel% EQU 0 (
   set tipo=%string%
   goto :confirmar)
if %errorlevel% EQU 1 (
   cls
   color C0
   title %err%
   %ls%
   %jpl% ³ %dnp%  ³
   %li%
   %put%
   pause>nul
   goto :inicio
 )

:: ====================================================
:: Confirma se você quer continuar com o processo.
:: ====================================================
:confirmar
color 0C
title CONFIRMAR
mode 52,7
cls
%jpl% Confirme essas informa‡äes antes de prosseguir!
echo. DRIVE: "%drive:~0,1%:'
echo. TIPO: %tipo%
echo.
choice /C SN /M " Escolha S para confirmar ou N para Cancelar: "
if %errorlevel% equ 1 (goto :entrar)
if %errorlevel% equ 2 (goto :inicio)

:: ====================================================
:: Processo para executar o programa principal.
:: ====================================================
:entrar
color 0E
TITLE FIM DO PROCESSO
cls
:: força o encerramento dos app de execução do VBS.
taskkill /f /im wscript.exe >nul
taskkill /f /im cscript.exe >nul
cls
:: entra no pendrive
pushd %drive:~0,1%:
:: Muda os atributos iniciais para execução efetiva.
attrib -R -S /S /D * >nul
:: verifica arquivos do maliciosos e exclui eles.
if exist %f1% (del /q /s /f %f1% >nul)
if exist %f2% (del /q /s /f %f2% >nul)
if exist %f3% (del /q /s /f %f3% >nul)
if exist %f4% (del /q /s /f %f4% >nul)
if exist %f5% (del /q /s /f %f5% >nul)
:: Restaura todo o pendrive.
attrib -R -A -S -H /S /D *
:: restaura a pasta systemvolumeinformation
attrib +H /S /D "System Volume Information">nul
%jpl% Processo Conlu¡do!!!
start %drive:~0,1%:
ping -n 5 0 >nul
exit

Copie e cole no bloco de notas salve como: HiddenPendrive.BAT

INSTRUÇÕES

PASSO 01 - Depois que você salvar o código-fonte, execute o arquivo em lotes, e a seguinte tela será mostrada.

Figura 01 - Tela inicial do Programa

PASSO 02 - Você Digita a letra do drive do seu Pendrive, veja na imagem onde achar essa letra do drive. Vá em "Meu Computador" e veja letra do drive:

Figura 02 - Letra do Pendrive

PASSO 03 - Agora que já sabe a letra do drive, você pode digitar no programa, dê "enter" após isso.

Figura 03 - Digitando a letra do drive:

Tendo em vista que o programa em lotes não permite o uso nos discos fixos do sistema, e na instalação do windows, ocorrerá a negação do para prosseguir, caso seja um drive fixo (HDD).

Figura 04 - Digitando o drive da instalação do windows

Observe abaixo o retorno de erro, caso seja digitado um drive fixo.

Figura 05 - A unidade não foi permitida (volta ao início.)

Outro caso é, se o drive solicitado existir ou não. Se o programa em lotes não encontrar o drive solicitado, então emitirá uma mensagem de "Drive não encontrado" (volta a tela inicial).

Figura 06 - Erro de drive não encontrado

PASSO 04 - Depois de ter encontrado o drive existente, o arquivo em lotes irá perguntar se você confirma o não o prosseguimento desta etapa, depois dessa fase todo o processo será automático.

Figura 07 - Tela de confirmação para prosseguir ou não.

Figura 08 - Tela de processo concluído.

PASSO 05 - Após ter concluído o processo final, será aberto o pendrive com a restauração dos arquivos ocultos, exclusão dos arquivos se existirem: VBS, PIF, CMD, COM, LNK.

OBS.: Este programa em lotes, tem a finalidade de recuperar arquivos ocultos, e não apagados como alguns pensam, apenas muda os atributos para serem visíveis e lidos pelo usuário. Se o formato estiver em .DAT, então este programa em lotes não recuperar em sua totalidade.

Você pode utilizar este código-fonte para estudos, fiquem a vontade para modificarem como quiserem para seus fins, esperamo que seja útil.

Comentem abaixo nos comentários, sugestões ou críticas são todas bem vindas.

POWERED

ACESSE NOSSAS REDES SOCIAIS

Inscreva-se no Canal